Charting with Chris

Lines and Colors and Clouds Oh My! - Thinkorswim Thinkscript

2009-01-31T10:45:00.000-08:00

I have been playing around with the "AddCloud" functionality within the Thinkscript API and came up with a variation on the GMMA strategy I call GMMA_Cloud, combined with what I call the ChrisStoplight system. This system is effectively 3 indicators built into one, the RSI up top, the DMI in the middle, and the StochasticMomentumIndex down below. Rather than focusing on the lines that make up the indicators, I've decided it's more important to keep track of the relationship between them.

The concept here is I believe that our brains are designed to deal more with spacial / color relation than trying to distinctly interpret lines all saying different things. My goal is to be able to glance at my chart and immediately get a feel for the movement of the security (in my case, forex pair). When all colors agree, odds are statistics are in your favor and it is reasonable to enter in agreement with the color.

The GMMA_Cloud consists of two clouds, the difference between the 3 and 15 ema is one cloud, and the difference between the 30 and 60 ema is the other.

I don't have a distinct strategy built up for this setup, as there are a lot of places for trader discretion that every trader will handle differently. The main idea is to use the GMMA clouds, combined with the RSI and DMI to determine trend and use the Stochastics to determine pinpointed entries. I'm leaning toward exits being targeted at daily pivot point levels unless the trend breaks sooner.

#Name:             GMMA_CLOUD
#Programmed By:    Chris Ball (chris.m.ball@gmail.com) on 1/31/09
#Posted At:        http://chartingwithchris.blogspot.com
#Description:      This is a cloud representation of the Guppy Multiple Moving Average system using only the exterior EMA's for the two groups.

declare upper;

input price = close;
input displace = 0;

def length3ema = 3;
def length15ema = 15;
def length30ema = 30;
def length60ema = 60;

plot avgexp3 = ExpAverage(data = price[-displace], length = length3ema);
avgexp3.SetDefaultColor(Color.Gray);
plot avgexp15 = ExpAverage(data = price[-displace], length = length15ema);
avgexp15.SetDefaultColor(Color.Gray);

AddCloud(avgexp3, avgexp15);

plot avgexp30 = ExpAverage(data = price[-displace], length = length30ema);
avgexp30.SetDefaultColor(Color.Gray);
plot avgexp60 = ExpAverage(data = price[-displace], length = length60ema);
avgexp60.SetDefaultColor(Color.Gray);

AddCloud(avgexp30, avgexp60);

#Name:             ChrisStoplight
#Programmed By:    Chris Ball (chris.m.ball@gmail.com) on 1/31/09
#Posted At:        http://chartingwithchris.blogspot.com
#Description:      This indicator is truly a representation of 3 indicators (RSI, DMI and the StochasticsMomentumIndex).

declare lower;

plot rsi1 = if RSIWilder(length = 14)."RSI" >= 50 then 10 else 9;
plot rsi2 = if RSIWilder(length = 14)."RSI" < 50 then 10 else 9;

AddCloud(rsi1, rsi2);

plot dmi1 = if DMI(length = 14)."DI+" >= DMI(length = 14)."DI-" then 8 else 7;
plot dmi2 = if DMI(length = 14)."DI+" < DMI(length = 14)."DI-" then 8 else 7;

AddCloud(dmi1, dmi2);

plot sto1 = if StochasticMomentumIndex()."SMI" >= StochasticMomentumIndex()."AvgSMI" then 6 else 5;
plot sto2 = if StochasticMomentumIndex()."SMI" < StochasticMomentumIndex()."AvgSMI" then 6 else 5;

AddCloud(sto1, sto2);

rsi1.setDefaultColor(Color.Gray);
rsi2.setDefaultColor(Color.Gray);
dmi1.setDefaultColor(Color.Gray);
dmi2.setDefaultColor(Color.Gray);
sto1.setDefaultColor(Color.Gray);
sto2.setDefaultColor(Color.Gray);

As can be seen in the above picture, there are usually several trading opportunities, depending on the time frame you're analyzing. I've been focusing on the 30 and 15 minute time frames. The idea is to trade when all colors are in agreement and get out when 1 or 2 start to go against your position. Due to the vast amount of trader discretion involved, I'd say my system is something to toy with and use as a starting base for creating your own strict rules. Without rules and money management, there's no way to consistently make money! Hopefully this will spark some inspiration with my fellow swimmers.

Cheers,
Chris

Most recent charting setup - Thinkorswim

2008-11-30T19:45:00.000-08:00

I've been juggling with a variety of trading strategies and as of late, I've settled on a unique combination of indicators that I am looking to test out over the next week or so. Here's a quick top-level view of the main trading concepts integrated into my setup:

1. Elder Impulse System
2. Person Pivot Point System
3. Guppy Multiple Moving Average System
4. Elder Triple Screen System

You'll notice that I managed to create what appears to be a sly modification to PersonsPivots and have integrated the impulse system into the daily pivot line so that I have the most robust way of displaying the information. You'll also notice that I'm using a slight variation of the usual slow stochastics. I find the stochastics momentum index to be slightly less prone to whipshaws but it appears to deliver similar results otherwise.

Bollinger Band BBSqueeze - Thinkorswim Thinkscript

2008-11-21T20:36:00.000-08:00

Through some testing I was performing over the last week, I wrote my own variation of the popular concept of bollinger band squeezes. This one is pretty unique:

1. It is based off of the SMA-based bollinger bands (can be changed to EMA if preferred).
2. It has a configurable period length for the bollinger bands.
3. This configurable period length is also used in calculating the average squeeze value of the bands, which are then halved to determine the squeeze threshold.

Essentially, anything below the threshold line as I call it, and it becomes colored indicating a squeeze of the bands. Red as it tightens, green as it widens. Once the band widens enough for the colored bars to turn back to dark gray, you essentially have a breakout on your hands. Please refer to the sample screen shot of this indicator down below.

#Name:             BBSqueeze
#Programmed By:    Chris Ball (chris.m.ball@gmail.com) on 11/21/08
#Posted At:        http://chartingwithchris.blogspot.com
#Description:      This is a bollinger band squeeze indicator with a dynamically generated threshold used to determine whether a squeeze is tight or not.  Please refer to my blog for further details.

declare lower;

input length = 18;

plot squeeze = BollingerBandsSMA(length=18)."UpperBand" - BollingerBandsSMA(length=18)."LowerBand";

def thresh = (sum(squeeze, length*5) / (length*5))*0.50;

squeeze.setPaintingStrategy(paintingstrategy.histogram);
squeeze.assignValueColor(if squeeze <= thresh and squeeze <= squeeze[1] then Color.Red else if squeeze <= thresh and squeeze > squeeze[1] then Color.Green else Color.Dark_Gray);

plot squeezeThreshold = thresh;
squeezeThreshold.setDefaultColor(Color.Yellow);

Gator Histogram - Thinkorswim Thinkscript

2008-11-06T08:27:00.001-08:00

For those of you familiar with the books by Bill Williams, he references what he calls the "gator histogram", based off of the alligator indicator. During my readings of his Chaos Theory book, I felt compelled to code this indicator just to get a better feel for it. I'm sure there are others out there who would like to make use of it as well, so here it is!

#Name:             GatorHistogram
#Programmed By:    Chris Ball (chris.m.ball@gmail.com) on 11/6/08
#Posted At:        http://chartingwithchris.blogspot.com
#Description:      The gator histogram is based off of the alligator indicator, both of which are referenced in numerous books by Bill Williams.

def Jaw = Average(close[8], 13);
def Teeth= Average(close[5], 8);
def Lip= Average(close[3], 5);

plot upperHist = AbsValue(Teeth - Jaw);
upperHist.SetPaintingStrategy(PaintingStrategy.HISTOGRAM);
upperHist.AssignValueColor(if upperHist > upperHist[1] then Color.Green else Color.Red);

plot lowerHist = -1 * AbsValue(Lip - Teeth);
lowerHist.SetPaintingStrategy(PaintingStrategy.HISTOGRAM);
lowerHist.AssignValueColor(if lowerHist > lowerHist[1] then Color.Red else Color.Green);

plot zero = 0;
zero.SetDefaultColor(Color.Red);

Elder Impulse System - Thinkorswim Thinkscript

2008-11-02T07:35:00.000-08:00

I've had a few emails since my post yesterday asking about the Elder Impulse System and if I could provide some code for that. Since I just so happened to have already written that before, you bet!

#Name:             ElderImpulse
#Programmed By:    Chris Ball (chris.m.ball@gmail.com) on 11/2/08
#Posted At:        http://chartingwithchris.blogspot.com
#Description:      This study can be adopted for display in many formats, however by default, it will display itself as a dot below each candle for the day.  Think of this system as telling you what you "may" do, rather than what you "must" do.  Alexander Elder created this system as a means of filtration rather than recommendation.

input length = 13;

def EMA = MovAvgExponential(length=length)."AvgExp";
def MACDHist = MACDHistogram()."Diff";

def impulseSignal = if (EMA < EMA[1] and MACDHist < MACDHist[1])
                    then 0
                    else if (EMA > EMA[1] and MACDHist > MACDHist[1])
                    then 1
                    else -1;

plot signal = low*0.95;
signal.assignValueColor(if impulseSignal == 1 then Color.Green else if impulseSignal == 0 then Color.Red else Color.Blue);
signal.setpaintingstrategy(paintingstrategy.points);
signal.setLineWeight(3);
signal.hideBubble();

Have fun!

Current Charting Setup - Thinkorswim TOS Charts

2008-11-01T19:09:00.000-07:00

I've had a number of emails over the last couple days from visitors asking me what my current charting setup looks like, so I figured I'd show a sneak peek.

Having read through "Trading for a living" and "Come into my trading room" by Alexander Elder, I must admit that there are certain aspects of his trading style that will probably always be a part of my setup moving forward and are evident in my layout.

You'll notice a couple odd things about my layout:
1. I have a 6m weekly candle-trend chart in the upper left gadgets area. The only thing added to this chart is my custom BallAutoEnvImpulse study. Essentially it is a mash up of a few different trading band concepts, integrated with the Elder Impulse system. I tend to treat this as Elder does with the weekly view, as part of the Triple Screen trading system. I look to make sure I'm never violating the weekly impulse. Other than for that purpose, I don't wish to dedicate more screen space to the weekly view which is why it's off in the corner.

2. The primary left chart is your basic 3m daily candle-trend chart, mixed with a more reader-friendly MACD and ADXR indicator.

3. The primary right chart is your basic 3m daily Heikin Ashi candle chart, mixed with your standard slow stochastics and Chaikin oscillator.

While I'm currently seeing how I feel about the Chaikin oscillator, I find that it is very similar to the Force Index that Elder pushes in his books. Either one serves essentially the same purpose.

I hope that you've found this informative insightful and if you have any questions, tough! Just kidding, you're encouraged to leave a comment on this blog, that way others can benefit from the same question/answers. You're also welcome to send me an email however I tend to get a lot sometimes so I don't always manage to get back to each and every one. Until next time...Chris.

Elder Thermometer - Thinkorswim Thinkscript

2008-10-26T15:43:00.000-07:00

I put together another one of Alexander Elder's indicators over the last week or so that essentially mimics his description of the thermometer indicator. Rather than regurgitating his words on interpretation, google has plenty of references. Now onto the good stuff:

#Name:             Elder Thermometer
#Programmed By:    Chris Ball (chris.m.ball@gmail.com) on 10/26/08
#Posted At:        http://chartingwithchris.blogspot.com
#Description:      This is a thermometer system, as described by Alexander Elder, that depicts tranquil versus volatile times for entry and exit of positions.

declare lower;
input length = 13;

def highVal = AbsValue(high - high[1]);
def lowVal = AbsValue(low - low[1]);
def plotVal = if (highVal > lowVal) then highVal else lowVal;

plot therm = plotVal;
therm.setPaintingStrategy(paintingstrategy.histogram);

plot emaLine = MovAvgExponential(length=length, price=plotVal);
emaLine.setDefaultColor(Color.White);

therm.assignValueColor( if therm < emaLine 
                            then Color.Cyan
                        else if therm > emaLine 
                        and therm < emaLine*3 
                            then Color.Yellow
                        else Color.Red
                       );

Donchian Channels - ThinkorSwim ThinkScript

2008-10-23T08:48:00.001-07:00

I'm feeling nice today and figured I'd also contribute the code I put together for Donchian Channels since they aren't included by default. For those of you out there who haven't heard of these before, I'd recommend googling the term "turtle trader". You'll get the idea soon enough!

#Name:             DonchianChannel
#Programmed By:    Chris Ball (chris.m.ball@gmail.com) on 10/23/08
#Posted At:        http://chartingwithchris.blogspot.com
#Description:      This is a channel system that is used frequently for trend trading.  Google the term "turtle trader" for more information.

input length = 20;

plot upperBand = Highest(high[1], length);
plot lowerBand = Lowest(low[1], length);
plot middleBand = (upperBand + lowerBand) / 2;

upperBand.SetDefaultColor(Color.Cyan);
lowerBand.SetDefaultColor(Color.Cyan);
middleBand.SetDefaultColor(Color.Cyan);

ADX Histogram - ThinkorSwim ThinkScript

2008-10-23T08:39:00.000-07:00

For those of you who like using the ADX technical indicator, I saw a newsletter that had a "histogram" version of the ADX line and I thought it looked easier to digest, so I went ahead and added some modifications to the one that comes with ThinkorSwim. Since all I did here was add on some additional code, I don't take credit for the bulk of what is there, merely my histogram conversion.

declare lower;

input length = 14;

def hidiff = high - high[1];
def lodiff = low[1] - low;

def dmim = if (hidiff < 0 and lodiff < 0) or hidiff >= lodiff then 0 else lodiff;
def dmip = if (hidiff < 0 and lodiff < 0) or lodiff >= hidiff then 0 else hidiff;

rec wdmim = compoundValue("historical data" = Average(dmim, length), "visible data" = (dmim + wdmim[1] * (length - 1)) / length);
rec wdmip = compoundValue("historical data" = Average(dmip, length), "visible data" = (dmip + wdmip[1] * (length - 1)) / length);
rec volty = compoundValue("historical data" = Average(TrueRange(high, close, low), length), "visible data" = (TrueRange(high, close, low) + volty[1] * (length - 1)) / length);

def dip = 100 * wdmip / volty;
def dim = 100 * wdmim / volty;

def dx = if (dip + dim > 0) then 100 * AbsValue(dip - dim) / (dip + dim) else 0;
rec va = (if IsNaN(va[1]) then 0 else va[1]) + dx;
rec val = compoundValue(length = length, "historical data" = va / (TotalSum(1) + 1), "visible data" = (val[1] * (length - 1) + dx) / length);

plot ADX = val;
ADX.AssignValueColor(if ADX > ADX[1] then 
                       Color.UPTICK 
                    else 
                       if ADX < ADX[1] then 
                          Color.DOWNTICK 
                       else 
                          GetColor(1)
                    );

ADX.SetPaintingStrategy(PaintingStrategy.HISTOGRAM);

Elder SafeZone Stop System - ThinkorSwim Thinkscript

2008-10-19T13:33:00.000-07:00

Throughout my reading of the book "Come Into My Trading Room", there was a great reference to what Dr. Elder called the "SafeZone" system. After a number of hours of testing, troubleshooting and revising my code, I arrived at a very concise finished product that I know will be valued by other ThinkorSwim users, so here's my study. All I ask in return is that if you post this elsewhere on the net that you give me credit and keep the comments in the script. You'll notice that by default, when you add the study, it does not appear plotted on your graph. This was intentional, as the way I intend to use this is to simply uncheck the "hide plot" feature on it and choose the correct trend option (Up/Down) when I need to see my SafeZone, otherwise I personally prefer that it remain invisible. Good trading my friends!

#Name:             ElderSafeZone
#Programmed By:    Chris Ball (chris.m.ball@gmail.com) on 10/19/08
#Posted At:        http://chartingwithchris.blogspot.com
#Description:      This study is a STOP system indicator, originally derived from the book "Come Into My Trading Room" by Dr. Alexander Elder

input coeff = 2.5;
input lookbackLength = 15;
input trendType = {default Up, Down};

def count;
def diff;
def totalCount;
def totalSum;
def penAvg;
def safety;
def finalSafety;

switch(trendType)
{
    case Down: 
        count = if (high > high[1]) then 1 else 0;
        diff = if (high > high[1]) then high - high[1] else 0; 
        totalCount = sum(count, lookbackLength);
        totalSum = sum(diff, lookbackLength);
        penAvg = (totalSum / totalCount);
        safety = high[1] + (penAvg[1] * coeff);
        finalSafety = Min(Min(safety, safety[1]), safety[2]);
    case Up: 
        count = if (low < low[1]) then 1 else 0;
        diff = if (low < low[1]) then low[1] - low else 0; 
        totalCount = sum(count, lookbackLength);
        totalSum = sum(diff, lookbackLength);
        penAvg = (totalSum / totalCount);
        safety = low[1] - (penAvg[1] * coeff);
        finalSafety = Max(Max(safety, safety[1]), safety[2]);
}

plot Stop = finalSafety;
Stop.setDefaultColor(Color.Green);
Stop.setStyle(Curve.Short_Dash);
Stop.hide();

Example:

Trials and tribulations on the stock market!

2008-10-19T11:11:00.001-07:00

Boy the last few weeks have taught me some lessons! I sure missed the mark on the VIX. Hopefully that will still work out by December / January. Who would have thought we'd be seeing the VIX pass the 80 mark? For those of you who are familiar with some of the books by Dr. Alexander Elder, I have been obsessively reading through his books lately ("Trading for a living", "Come Into My Trading Room") and have learned a great deal about myself and my approach to trading.

Essentially, I've been trading almost completely on emotion, with no planned exit strategies, nor any sort of consistent money management approach. These are all things that I am in the midst of working on (as I am sure many other traders are as well). Through the pain of seeing way too much of my bankroll go down the tubes as the VIX skyrockets, I've started to acknowledge the fact that I need to rebuild my strategy and let go of any forms of fear or greed. Most importantly, I have acknowledged that I need to start sticking to planned STOP exits. With options, this if of course a bit more tricky than with stocks, since you don't know the price your option will be when a stock price hits your STOP. This is where discipline is crucial, so we'll see how well I can stick to it!

Over the last week I have programmed several of Elder's indicators into my trading platform (Thinkorswim), and completely transformed the way in which I perform technical analysis to more closely resemble his very sound approach. Please note that I have taken some personal liberties in determining configuration values that best suit my needs but these are flexible and should not be considered set-in-stone. Here's one such example of the Dow Jones Industrial Average:

Left Side Configuration:
Daily View
13 Period EMA with 10% Envelope
12-26-9 Period MACD Histogram combined with a 13 Period Elder Impulse Setup
2 Period Force Index

Right Side Configuration:
Weekly View
26 Period EMA with 20% Envelope
12-26-9 Period MACD Histogram combined with a 26 Period Elder Impulse Setup
2 Period Force Index

The first thing that I noticed was arrow #1. The force index is making lower high's and higher lows. This means that we're in for a breakout within the next 2-3 days. Arrow #4 confirms this by showing what appears to be a "bear flag" pattern. This seems to be telling me that we're likely going to see the DJI retest the lower support that we set last week. You'll notice that arrow #3 shows that the weekly impulse states that we're still in shorting period, while arrow #2 shows that the daily impulse indicates we're in an undecided state. Overall, this picture paints a somewhat dreary week ahead.

Candlestick Analysis - AmericanBulls Validity In Question

2008-10-12T12:08:00.000-07:00

I recently started heavily diving into candlestick analysis, as I feel that it has a lot to offer the technical analyst. I picked up a couple really good books on the subject (Candlestick Charting Explained by Gregory L. Morris and Getting Started In Candlestick Charting by Tina Logan).

One of my aspirations that I've been quietly building over the last few months is a custom python-based stock scanning system at home. So far I've built in a number of great scans that you can't find virtually anywhere on the net. One of the few places that I noticed that offers what appeared to be strong candlestick analysis was American Bulls (americanbulls.com). I've been observing their site off and on for quite some time now and have come to the conclusion that the site is downright wrong most of the time, not to mention completely misleading. Their concept is sound, but their execution and representations are not valid.

I started to notice analysis discrepancies when I compared my custom-built system results to their analysis. My system scans roughly 850 symbols that I originally wheedled the full set of stock symbols out there down to (based on decent volume, price, etc...). With that being said, my system outputted the following for the "Hammer / Hanging Man" scan. I still use my own judgment to determine the preceding trends, but you'll see that the accuracy for the candlestick analysis is very sharp:

Beginning Candlestick Study - "Hammer / Hanging Man" scan...
ARD
ED
FDG
GT
IBB
IKN
MGM
PAYX
RRD
SD
TWC
VLTR
Total Hits Found: 12

I walked through each of these results and every single one of them is a hammer in this instance, preceded by a downtrend. I started checking some of these out on americanbulls.com and quickly noticed major issues. Take the following for example:

Symbol FDG. The actual price chart looks like this for it...

Compare this to what is indicated by american bulls...

You'll notice that their analysis indicates FDG is currently exhibiting a "high wave" candle. This is flat out wrong. Based on confirmations from both of my books, high wave candles look absolutely nothing like hammers. A high wave candle is known for having a small body with long shadows on both ends. In fact, there's a pretty good example of a high wave candle in the same picture above (third candle from the right). You'll notice that the body is relatively small and not close enough to the top to be considered a hammer.

In addition to very confusing candlestick analysis, their system that runs down the right side of the site showing profit has two major problems:

1. Their entry prices used to calculate their profits are based (I think) on the opening price for the day. So they will wait until the close of a particular day to get confirmation, then essentially make note that their entry was at the beginning of that very same day! This is obviously using future data to change the past.

2. Where's the commission costs? If you were to tack that on, you'd notice that most of that profit (even when calculated incorrectly as stated in #1) goes away.

Needless to say, I have no vested interest in their site one way or the other, but I find it disturbing that such a prominent site on the subject shows so many problems and yet countless people use their data for making financial decisions. Be careful out there my friends...Chris.

Revised $700 Billion Dollar Bailout Passes - VIX Impact Coming Soon?

2008-10-05T18:47:00.000-07:00

To those scratching their heads as to just how high the VIX is likely to travel, you're not alone. With the passing of the revised $700 billion dollar bailout plan, one can only hope that it will finally instill a more calming impact on the market. Over the span of the last week or so, I've actually added many more contracts to my current position, so I too am banking on it dropping by December / January.

I've done some Fibonacci analysis using a long term retracement plot spanning from the Dec 06 monthly low through to the high established last week. Zooming back in to a daily view, it looks like our first retracement zone we'll need to break through is the $39.17 mark. If we get past that which I think we will, $33.46 should be our next stop. The one positive sign I'll say is that Friday left us with a small candlestick hammer at the same time our stochastics indicate that we're just reaching an overbought state in a ranging price action state.

For those of you wondering what the "Ball_Breakout_Detector" is at the bottom, that's actually an indicator I've been building out to help me pay closer attention to breakouts versus ranging trades. It's still a work in progress, but it is essentially indicating that we are in a ranged trade area with a warning that we may enter a breakout soon.

CBOE VIX Volatility Index - Primed To Fall Hard & Fast

2008-09-28T15:48:00.000-07:00

While I'm sure I'm not the only one to be gasping at the complete insanity we call a marketplace over the last week, one thing that did catch my attention in a positive light was the VIX index. Over the last couple weeks, we've had some very high and very rare spikes. While spikes are to be expected in a near market collapse situation (we'll probably know tomorrow when the Feds likely announce an agreed-upon bailout plan), these spikes have been just screaming for some option PUTS looking out over the next couple months. Take a look at the following dual-graph setup I've constructed, showing numerous high-reliability divergences:

You'll notice to the left that we have lots of instances of bearish divergence / confirmation from Stochastics, RSI, Accum/Dist and Williams %R. If this doesn't tell you to look for a drop, I don't know what does - that's 4 very solid indicators all saying the same thing.

I currently have some DEC08 22.5 PUTS at an averaged entry of 1.40 per contract so I'm sitting pretty solid for some nice market calming, if the Feds can reach an agreement that is. I can easily see the VIX returning to values somewhere around 20-25. If that happens, let's say we hit 22.5 dead on between now and December, that should bump the 22.5 PUTS up to around 9.00 to 10.00 I'm estimating. So we're looking at an approximate return of 7 times my investment in 2.5 months!

Williams %R - The Price Headley Way

2008-09-21T18:01:00.000-07:00

I was watching an online lecture by Price Headley today and he dove into one of his more straightforward methods for trading. He makes use of the Williams %R indicator, however he sets the bar period to a value of 30.

The following is my interpretation of his methods with a random equity choice during a recent period (picked at random). One thing interesting about my graphical representation of his method is that I show both a "win" and a "loss" to show that this system is indeed realistic and not a holy grail.

One thing I'd like to highlight is the concept of "closing stops" as opposed to standard automated "stops". Closing stops in this instance, I believe, are considered to be manual stop orders placed each day during the last 15 minutes of the market. The reason for this manual management of stops is to avoid being stopped out during intraday trading. With that being said, on with the example:

Before walking through these two plays, let me explain my color coding strategy for the vertical lines you see within the Williams %R indicator. Blue = Signal Day, Green = Confirmation Day, Yellow = Re-test Day, Red = Exit Day. A signal day represents the upward (Bullish)/downward (Bearish) crossover of the Williams %R line. Once this crossover happens, if it is an upward crossover, we make note of the high for the signal day and wait for confirmation by seeing a bar close above the signal day high. Likewise, if it is a lower crossover, we make note of the low for the signal day and wait for confirmation by seeing a bar close below the signal day low. For both of these instances, please realize that confirmations can only be issued so long as the Williams %R line has not crossed back inwards. If the line crosses back inwards and then outwards before a confirmation day is issued, my interpretation would be that we have a new signal day and corresponding high/low to consider for confirmation.

Let's take the first trade in my example. The first signal day was not issued a confirmation before the Williams %R line dipped back inward. A second signal day was triggered (second vertical blue line) so we then made note of the high for that day by drawing the light blue horizontal trendline. We see that our confirmation day came two days after our signal day, and we entered our position somewhere near the close of $59.82 at the tail end of the confirmation day. Here we also made note to set an initial stop at the low of our signal day at $56.86. Three bars later we were faced with a re-test day because the day closed where the Williams %R line crossed back inward. So in this case, we made note of the low for the re-test day and would then apply it as a closing stop manually during the last 15 minutes of the market each day until we either stopped out or the Williams %R crossed back outward. In this case, it crossed back outward and we could then relax and watch the climb. We received another re-test day on 7/8/08 so we upped our old close stop value to the new signal day low of $67.39. Williams %R again crossed back outward, indicating our ride was not over. Our final re-test day triggered on 7/16/08. While the low of our new re-test day was $70.27, by the time the market was nearing close, the price was already below this value so it was technically below where we would have manually issued our close stop, so we would have exited the trade somewhere around the close at $69.44 on 7/17/08. Our ride lasted from 6/10/08 to 7/17/08 with a net gain of $10.02 in stock price. Using "ThinkBack" on Thinkorswim, I would probably have purchased the JUL08 64 Call for 2.10. On 7/17, this option last sold for 5.60, netting $350 on an initial investment of $210 in approximately 5 weeks.

Our second example was not as fortunate. A signal day was triggered on the short side, followed by a confirmation day the very next day. We would have entered the position toward the end of the day at around close for $63.28. Two bars later Williams %R crossed inward, triggering a re-test day. We then made note of the new closing stop of $66.33 to replace our initial stop of $67.80 derived from the low of our initiating signal day. The Williams %R crossed back outward, relieving our concerns for exiting for a couple days, but then we were hit with another re-test day signal. The high of our new re-test day signal was the exact same as the previous re-test day ($66.33) so our close stop value remained the same and we sat tight to see if we'd make it another day. Unfortunately market close on judgment day wasn't so kind and we stopped out at near close at $67.04. This ride lasted from 8/11/08 to 8/19/08. I would probably have purchased the SEP08 61 Put for 2.25. On 8/19, this option last sold for 0.75, losing $150 on an initial investment of $225 in a little over a week.

So if you were to take into account both our win and our loss, we still netted $200 between these two plays, even though we weren't always right, not too shabby! Part of the lessons I am seriously considering right now is managing those stops and learning to limit my losses. I hope this has been both informative and eye-opening. I will likely be attempting to implement this "for real" over the next week, so we'll see how it goes! Until next time...Chris.

PUT Candidate: TRA

2008-08-23T15:42:00.000-07:00

This stock chart stood out as very interesting, due to the repeated up/down pattern. I applied some trendlines and tossed on some potential price points where this stock "might" go.

As you can see in the chart above, this stock appears to be losing its trend if you focus on the ADX component of the DMI indicator, although I think it's just restablishing the new upward trend. The DI+ just crossed over the DI-. The positive MACD crossover and parabolic SAR forming underneath all suggest that this stock may try to reach a bit higher before rebounding back down to the support level.

It will be interesting to see if it reaches the upper-marked price point of $57.50. I will be looking for the turning point to play a potential PUT for the down trend.

Needless to say, I am not a professional investor - actually a software engineer, so please make sure to do your own research before jumping into any investments. I've always been a big fan of technical analysis, but up until recently I only dabbled in straight stocks. Playing the options market can be a bit more risky if you're unclear about what you're doing. So if you're unclear about any concepts related to basic options trading, I highly recommend picking up a good book or two, or checking out the education section at yahoo finance or the likes. Good luck! -Chris